Re: ]] XL-mania [[ Menjumlahkan kolom sesuai dengan kriteria bulan

 

Saya tambahkan ya ki,,

=INDEX(SUM(((--$B$2:$M$2)<=$O$1)*($B3:$M3)),)

=SUM(INDEX(((--$B$2:$M$2)<=$O$1)*($B3:$M3),))

=SUM($B3:INDEX($B3:$M3,$O$1))

=SUM(OFFSET($B3,,,,$O$1))

=SUM($B3:$M3 OFFSET($B3,,,,$O$1))

=SUM($B:$M OFFSET(3:3,,,,$O$1+COLUMN($B3)-1))

=SUM(OFFSET(3:3  $B:$B,,,,$O$1))

=SUM(3:3  OFFSET($B:$B,,,,$O$1))

(dan masih banyak varian lainnya yang dapat digunakan)

File terlampir

>semoga bermanfaat

---

From: Ki Semprul <semprul.ki@gmail.com>
To: XL-mania@yahoogroups.com
Sent: Monday, February 20, 2012 5:33 AM
Subject: Re: ]] XL-mania [[ Menjumlahkan kolom sesuai dengan kriteria bulan

 

salah satu cara :

( 1 ) Array Formula di cell O3

=SUM(IF(--($B$2:$M$2)<=$O$1,$B3:$M3))

( 2 ) selain itu ada lagi  (formula biasa..)

=SUM(OFFSET($A3,0,1,1,$O$1))

( 2a ) malah karena adanya sifat optional pada beberapa arguments-nya, 

rumus tsb masih bisa dipangkas menjadi lebih pendek dan kekar spt ini

  / recommended karena pendek-nya

=SUM(OFFSET($A3,,1,,$O$1)

( 3 ) zamproduct ..?? juga ike..

=SUMPRODUCT((--$B$2:$M$2<=$O$1)*B3:M3)

( 4 ) masih bisa dicoba formula:

=SUM(INDEX($B3:$N3,1):INDEX($B3:$N3,$O$1))

( 5 )  selain itu kalau mau ber-rumit-ria, sambil belajar fungsi INDIRECT & ADDRESS

mumpung ada kasusnya

=SUM(INDIRECT(ADDRESS(ROW(),2)&":"&ADDRESS(ROW(),$O$1+1)))

( 6 )  Seandainya Baris B2:N2 berisi angka urut 1 sd 12 

       (bukan berupa data text tetapi data  Numners / Bilangan), maka rumusnya lebih  sederhana

=SUMIF($B$19:$M$19, "<=" & $O$1, $B3:$M3)

2012/2/17 Agus Iriyanto <agus.parepare@gmail.com>
> To.. XL-Mania..
> mohon bisa dibantu, formula yang tepat untuk menjumlahkan sejumlah kolom sesui dengan kriteria bulan. 

> lebih jelas ada di sisipan. terimakasih.

__._,_.___

Reply to sender | Reply to group | Reply via web post | Start a New Topic

Messages in this topic (4)

Recent Activity:

• New Members 64

Visit Your Group

+-:: XL-mania ::::::::::::::::::::----------------------------------+
| Delay pada posting disebabkan sibuknya momods dan leletnya        |
| koneksi dengan ind***t. bwakakakaka....
+-------------------------------------------------------------------+
| DILARANG : MLM, money game, OOT, iklan tanpa izin, SARA, testing, |
| pembicaraan pribadi, one line message,  melecehkan,  tidak sopan. |
+-------------------------------------------------------------------+
| Buat subjek yang kreatif, jangan : "tanya", "help", "mohon bantu" |
| Usahakan besar attachment < 200 kb. Gunakan  winzip  jika  perlu. |
+-------------------------------------------------------------------+
| Ajak teman-teman Anda bergabung dengan mengirim e-mail kosong ke  |
| XL-mania-subscribe@yahoogroups.com atau kirimkan mereka file dari |
| http://groups.yahoo.com/group/XL-mania/files/Promotion/           |
+-------------------------------------------------------------------+
| Berikan testimoni di :                                            |
| http://www.xl-mania.com/2008/06/testimoni-xl-mania.html           |
+-------------------------------------------------------------------+
| Message lama ada di :                                             |
| http://groups.yahoo.com/group/XL-mania/messages [perlu yahoo id]  |
| http://www.mail-archive.com/xl-mania@yahoogroups.com              |
+-------------------------------------------------------------------+

Switch to: Text-Only, Daily Digest • Unsubscribe • Terms of Use

.

__,_._,___