Sub MenyusunTabel()
' coded by: siti Vi / 28 dec 2010
'--------------------------------
' mengumumkan beberapa variables yg akan dipakai dlm prosedur ini
Dim sht As Worksheet '= mewakili tiap sheet dlm book
Dim TablePart As Range '= mewakili tiap komponen tabel
Dim NextPaste As Range '= mewakili cell : tempat akan ditempelkannya
' copy-an TabelPart
' membersihkan (data maupun formatting) koloms yg akan berisi tabelHasil
Columns("A:K").Clear
' cell pertama ("A1"): di set sebagai range NextPaste
Set NextPaste = Cells(1)
' Loop: mengunjungi setiap sheet (variable sht) pada workbook ini
For Each sht In Worksheets
' SYARAT: sheet hanya akan diproses jika nama sheet yg sedang dikunjungi
' TIDAK SAMA dengan nama SheetAktif (=sheet dimana tombol di-ceklik)
If sht.Name <> ActiveSheet.Name Then
' Range PrintArea pada sheet (sht) yg sedang dikunjungi: di set
' sebagai Range TablePart
Set TablePart = sht.Range(sht.PageSetup.PrintArea)
' lalu di-Salin (diingat dlm memory ClipBoard)
TablePart.Copy
' kemudian (data maupun formatting TablePart tsb) di-Tempelkan ke range
' yg PojokKiriAtasnya = range yg dikenal sebagai NextPaste
NextPaste.PasteSpecial xlPasteAll
' Posisi Cell NexPaste (=bukan data-nya lho ya..!) digeser ke bawah,
' sejauh / sebanyak baris yg ada pada range TabelPart
' maksodnya agar TablePart untuk Loop berikutnya DiTempelkan-nya
' tepat di bawah tabel tempelan terakhir
Set NextPaste = NextPaste.Offset(TablePart.Rows.Count, 0)
' batas akhir SYARAT
End If
' Batas Loop (perulangan)
Next sht
' setelah semua terCopy, sekarang dicopy pula: LEBAR-TIAP-KOLOM nya saja
NextPaste.PasteSpecial xlPasteColumnWidths
' mengosongkan ClipBoard / dlm hal ini menghilangkan tanda
' garis semut lasvegas pada range yg baru (terakhir) dicopy
Application.CutCopyMode = False
' CellPointer (posisi cell-aktif) ditaruh di H3, (supaya "bagoes !" gitu loch!) he he...
Cells(3, 8).Activate
' sekedar pemberitahuan kpd user: bahwa proses sudah kelar !
MsgBox "Penyusunan Tabel: telah selesai Boss !!", 64, "Thuing ... !"
End Sub
'-------------------------------------------------
' mudah mudahan penjelasan asal-asalan ini
' dapat ditangkap maksot-nya
'-------------------------------------------------
' bluewater, 28 Dec 2010
' siti Vi <setiyowati.devi@gmail.com>
' STDEV(i) <villager.girl@gmail.com>
'-------------------------------------------------
2010/12/24 andri apriyadi <andreemobile@yahoo.co.id>
>
> Dear Pakar Excel,
>
> Karena saya sama sekali awam masalah makro, mohon bantuannya untuk rumus makro yang dapat menggabungkan komponen tabel (header, isi tabel, dan footer) menjadi tabel utuh. Terima kasih atas pencerahannya.
>
> Saya sangat senang sekali bergabung di milis ini!
> Semoga XL-Mania dapat mencerdaskan kita semua!
>
> Regard
> Andree
| "if you are the most valuable assets, you will show up on the |
| balance sheet..." - oNo Wiqe |
| http://www.facebook.com/group.php?gid=37671048001&ref=mf |
+-------------------------------------------------------------------+
| DILARANG : MLM, money game, OOT, iklan tanpa izin, SARA, testing, |
| pembicaraan pribadi, one line message, melecehkan, tidak sopan. |
+-------------------------------------------------------------------+
| Buat subjek yang kreatif, jangan : "tanya", "help", "mohon bantu" |
| Usahakan besar attachment < 200 kb. Gunakan winzip jika perlu. |
+-------------------------------------------------------------------+
| Ajak teman-teman Anda bergabung dengan mengirim e-mail kosong ke |
| XL-mania-subscribe@yahoogroups.com atau kirimkan mereka file dari |
| http://groups.yahoo.com/group/XL-mania/files/Promotion/ |
+-------------------------------------------------------------------+
| Berikan testimoni di : http://www.friendster.com/xlmania atau... |
| http://www.xl-mania.com/2008/06/testimoni-xl-mania.html |
+-------------------------------------------------------------------+
| Message lama ada di : |
| http://groups.yahoo.com/group/XL-mania/messages [perlu yahoo id] |
| http://www.mail-archive.com/xl-mania@yahoogroups.com |
+-------------------------------------------------------------------+
Nenhum comentário:
Postar um comentário