Re: ]] XL-mania [[ tanya tentang cetak data validasi

 

Dear Pak Spd.,

Mungkin begini...

'----------------

Private Sub Cmd_Cetak_Multi_Click()

   ' Indri Hapsari / 22 Dec 2011

   '----------------------------

   Dim iPrint As Long

   Const pesan As String = _

     "NomorStart kok lebih besar dari nomorEnd ??" _

      & vbCr & "cetak dibatalkan.."

   

   ' jika nomor awal cetak LebihBesarD/P nr akhir

   If Range("P20").Value > Range("P22").Value Then

      ' munculkan teguran

      MsgBox pesan, 48, ThisWorkbook.Name

      ' akhiri program, tanpa mencetak

      Exit Sub

   Else    ' jika TIDAK....

      ' adakan pengulangan nomor dari... Ke Nomor...

      ' (sesuai yg tertulis di cell P20 dan P22)

      For iPrint = Range("P20").Value To Range("P22").Value

         ' setiap pengulangan: angka di O39 diganti

         Range("o39").Value = iPrint

         ' lalu di PrintOut

         Me.PrintOut

      Next iPrint

   End If

End Sub

Private Sub Cmd_Cetak_Semua_Click()

   Dim RecCount As Long, iPrint As Long

  ' menentukan jumlah baris data (tanpa menghitung Headingnya)

   RecCount = Sheets("TabelSiswa").Cells(1).CurrentRegion.Rows.Count - 1

   For iPrint = 1 To RecCount

      Range("o39").Value = iPrint

      Me.PrintOut

   Next iPrint

End Sub

Private Sub Cmd_Cetak1_Click()

   Me.PrintOut

End Sub

Private Sub Worksheet_Activate()

   ' mengantisipasi barangkali ada perubahan

   ' jumlah siswa (than.. Scroll Max disesuaikan dwong..)

   Set sTabel = Sheets("TabelSiswa").Cells(1).CurrentRegion

   ScrollBar1.Min = 1

   ScrollBar1.Max = sTabel.Rows.Count - 1

End Sub

'----------------------

Semua procedures tsb ditulis di Module Sheet yg akan diprint

workbook-contoh ada & dapat diunduh di sini:

-i-Haps-

2011/12/21 Sutrisno S.Pd <sutrisnomansa@yahoo.com>
>
> saya membuat file dengan data validasi, bagaimana cara mencetak data no tertentu dan semua data secara urut dengan macro. terima kasih. file saya sertakan pada attachment.

__._,_.___

Reply to sender | Reply to group | Reply via web post | Start a New Topic

Messages in this topic (2)

Recent Activity:

• New Members 76

Visit Your Group

+-:: XL-mania ::::::::::::::::::::----------------------------------+
| ayooo... coba cari XL-mania di linkedin.com                       |
| momods kebanyakan e-mail :(... unread di kantor 6 ribu lebih :(   |
+-------------------------------------------------------------------+
| DILARANG : MLM, money game, OOT, iklan tanpa izin, SARA, testing, |
| pembicaraan pribadi, one line message,  melecehkan,  tidak sopan. |
+-------------------------------------------------------------------+
| Buat subjek yang kreatif, jangan : "tanya", "help", "mohon bantu" |
| Usahakan besar attachment < 200 kb. Gunakan  winzip  jika  perlu. |
+-------------------------------------------------------------------+
| Ajak teman-teman Anda bergabung dengan mengirim e-mail kosong ke  |
| XL-mania-subscribe@yahoogroups.com atau kirimkan mereka file dari |
| http://groups.yahoo.com/group/XL-mania/files/Promotion/           |
+-------------------------------------------------------------------+
| Berikan testimoni di : http://www.friendster.com/xlmania atau...  |
| http://www.xl-mania.com/2008/06/testimoni-xl-mania.html           |
+-------------------------------------------------------------------+
| Message lama ada di :                                             |
| http://groups.yahoo.com/group/XL-mania/messages [perlu yahoo id]  |
| http://www.mail-archive.com/xl-mania@yahoogroups.com              |
+-------------------------------------------------------------------+

MARKETPLACE

Stay on top of your group activity without leaving the page you're on - Get the Yahoo! Toolbar now.

Switch to: Text-Only, Daily Digest • Unsubscribe • Terms of Use

.

__,_._,___