Re: ]] XL-mania [[ Cari Hari Senin Pertama Bulan Berikutnya.

 



masih penasaran dengan kasus ini.. dengan hormat di ajukan 4 formula alternatif (lagi)

 

versi tanpa bantuan add-in analisis tool

=DATE(YEAR(B5),MONTH(B5)+1,1)+MOD(8-WEEKDAY(DATE(YEAR(B5),MONTH(B5)+1,1),2),7)
=DATE(YEAR(B5),MONTH(B5)+1,1)+6-WEEKDAY(DATE(YEAR(B5),MONTH(B5)+1,1)-1,3)

 

versi dengan add-in analisis tool diaktifkan

=EOMONTH(B5,0)+1+MOD(8-WEEKDAY(EOMONTH(B5,0)+1,2),7)
=EOMONTH(B5,0)+7-WEEKDAY(EOMONTH(B5,0),3)

memanfaatkan fungsi weekday dengan argument#2  = 3 (yg menghasilkan Minggu = 0);

ternyata dapat membuat formula terpendek : 41 karakter (ada fungsi EOMONTH-nya), 

atau 73 karakter (tanpa fungsi EOMONTH); masih kalah pendek dgn floor-nya mas Kid.

 

Selalin formula yg telah ditulis di atas, dlm thread ini telah terkumpul koleksi sbb:

 

abee / array formula / 91 

'=INDEX(F7+ROW($1:$40),MATCH(1,(WEEKDAY((F7+ROW($1:$40)))=2)*(MONTH(F7)<MONTH(F7+ROW($1:$40))),0))

 

kid / formula / 71

=FLOOR(F7+32-DAY(F7),7)+2+(MONTH(F7)=MONTH(FLOOR(F7+32-DAY(F7),7)+2))*7

 

siti /  formula / 117

=DATE(YEAR(F7),MONTH(F7)+1,1)-WEEKDAY(DATE(YEAR(F7),MONTH(F7)+1,1),2)+

  IF(WEEKDAY(DATE(YEAR(F7),MONTH(F7)+1,1))=2,1,8)

 

ctv / formula / 77

=EOMONTH(B9,0)+1-WEEKDAY(EOMONTH(B9,0)+1,2)+(WEEKDAY(EOMONTH(B9,0)+1)<>2)*7+1

 

setiyowati / formula / 71

=EOMONTH(F7,0)-WEEKDAY(EOMONTH(F7,0))+7*(WEEKDAY(EOMONTH(F7,0)+1)<>2)+2

 

khozhot / formula / 149

=EOMONTH(F7,0)+IF(WEEKDAY(EOMONTH(F7,0))=2,WEEKDAY(EOMONTH(F7,0))-0,

   IF(WEEKDAY(EOMONTH(F7,0))>2,2-WEEKDAY(EOMONTH(F7,0))+7,2-WEEKDAY(EOMONTH(F7,0))))

 

pinjam 'closing salutation' dari pak anton: 

"> semoga bermanfaat..."

 

---

----- Original Message -----

From: Sukardi

To: XL-mania@yahoogroups.com

Sent: Friday, March 26, 2010 7:29 PM

Subject: ]] XL-mania [[ Cari Hari Senin Pertama Bulan Berikutnya.

Salam, ...
Numpang tanya, Bagaimana rumus untuk mencari tanggal / Hari Senin Bulan
berikutnya dari sel sebelah.
Atas bantuannya terima kasih.

__._,_.___

Reply to sender | Reply to group | Reply via web post | Start a New Topic

Messages in this topic (12)

Recent Activity:

• New Members 79

Visit Your Group

+-:: XL-mania ::::::::::::::::::::----------------------------------+
| Yahoo! Groups will be down for a scheduled outage on 1 Apr 2010   |
| http://www.facebook.com/group.php?gid=37671048001&ref=mf          |
+-------------------------------------------------------------------+
| DILARANG : MLM, money game, OOT, iklan tanpa izin, SARA, testing, |
| pembicaraan pribadi, one line message,  melecehkan,  tidak sopan. |
+-------------------------------------------------------------------+
| Buat subjek yang kreatif, jangan : "tanya", "help", "mohon bantu" |
| Usahakan besar attachment < 200 kb. Gunakan  winzip  jika  perlu. |
+-------------------------------------------------------------------+
| Ajak teman-teman Anda bergabung dengan mengirim e-mail kosong ke  |
| XL-mania-subscribe@yahoogroups.com atau kirimkan mereka file dari |
| http://groups.yahoo.com/group/XL-mania/files/Promotion/           |
+-------------------------------------------------------------------+
| Berikan testimoni di : http://www.friendster.com/xlmania atau...  |
| http://www.xl-mania.com/2008/06/testimoni-xl-mania.html           |
+-------------------------------------------------------------------+
| Message lama ada di :                                             |
| http://groups.yahoo.com/group/XL-mania/messages [perlu yahoo id]  |
| http://www.mail-archive.com/xl-mania@yahoogroups.com              |
+-------------------------------------------------------------------+

Switch to: Text-Only, Daily Digest • Unsubscribe • Terms of Use

.

__,_._,___