Re: ]] XL-mania [[ Automation Dropdown list berdasar dua data

DropDownList ex buatan Data > Validation itu memang 'dah terkenal sulit diatur-atur

lebih lanjut sesuai kehendak kita.

Cara yg sudah anda pakai itu sudah bagus, (data kanannya = dipanggil dgn VLookUp)

tetapi memang, selama memilih KodeAkun, kita tidak dapat melihat NamaAkun..

 

"Benda" semacam DropDownButton/List spt itu bisa juga dibuat dari ComboBox.

ComboBox (dari tollbar ControlToolBox) dah terkenal dapat diatur-atur sekehendak kita;

termasuk menampilkan data berkolom-kolom dan tidak semua harus dipilih (masuk ke box).

 

Sayangnya kalau mau otomatis, kita kudu tulis makronya (sedikit sih...)

 

'--vba code pada userForm Module---

Dim RefTabel As Range

 

Private Sub UserForm_Initialize()
   Dim i As Integer
   Set RefTabel = Sheets("SubSys").Cells(1, 1).CurrentRegion.Offset(1, 0)
   Set RefTabel = RefTabel.Resize(RefTabel.Rows.Count - 1, RefTabel.Columns.Count)
   RefTabel.Name = "DafAkun"
   IsInitialized = False
   CboKdAkun.RowSource = "DafAkun"
   CboKdAkun.BoundColumn = 1
   CboKdAkun.ColumnCount = 2
   IsInitialized = True
End Sub

 

Private Sub CboKdAkun_Change()
   If IsInitialized = True Then
      TxtNmAkun = RefTabel(CboKdAkun.ListIndex + 1, 2)
   End If
End Sub

 

Private Sub OKButton_Click()
   If CboKdAkun.ListIndex = -1 Then Exit Sub
   AktifSel(1, 0).NumberFormat = "dd MMM yyyy"
   AktifSel(1, 0) = DTPicker1
   AktifSel(1, 1) = CboKdAkun
   AktifSel(1, 2) = TxtNmAkun
   Unload Me
End Sub
'--------------

 

'----vba code pada SheesCODE Module ---

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
   If Target.Cells.Count = 1 Then
      If Target.Column = 2 Then
         If Target.Row > 4 Then
            Set AktifSel = Target(1, 1)
            Form_PartialInput.Show
         End If
      End If
   End If
   Cancel = True
End Sub
'----------------

 

bila makro tidak jalan, mungkin file mscomct2.ocx tidak ada di pc anda...

 

cmiiw

siti

 

 

---

----- Original Message -----

From: Kresna

To: XL-mania@yahoogroups.com

Sent: Sunday, January 24, 2010 2:08 AM

Subject: ]] XL-mania [[ Automation Dropdown list berdasar dua data

Buat para sesepuh excel...

Saya punya masalah untuk menginput data. (account code dan deskripsinya). Bagaimana membuat automatisasi dalam penginputan data berdasarkan dua tabel.
sementara ini saya bisa mengakali dengan menu drop down list, (tp yang muncul hanya berdasar satu tabel) dan kolom sebelahnya saya bisa menggunakan rumus vlookup.

Saya sudah mumet, coba utak atik tetep ndak bisa. Idenya pd saat menginput account code, muncul small window/drop down list, tetapi yang ditampilkan account code dan deskripsinya,
untuk mengurangi kesalahan penginputan account code.

Kalo menggunakan drop down list,selain hy menampilkan satu tabel, data account codenya harus berada pd di sheet yg sama,
bisa juga sih diakali dengan hide, tp bisa ndak yah..kalo dt account code ditempat sheet yg berbeda. Ini saya lampirkan file yg dimaksud.nlihat sheet account code.

sebelumnya terima kasih banyak...

Ria Kresna